Add git::subtree class to install git-subtree

Author: mcanevet

Modulefile

@@ -6,5 +6,5 @@ license 'Apache 2.0'
 summary 'module for installing git'
 description 'module for installing git'
 project_page 'https://github.com/puppetlabs/puppetlabs-git/'
-
+dependency 'puppetlabs/vcsrepo'
 

files/subtree/bash_completion.sh

@@ -0,0 +1,25 @@
+#!bash
+#
+# bash completion support for Git subtree.
+#
+# To use this routine:
+#
+#    1) Make sure you have installed and configured the core Git completion script, which is required to make this script work;
+#    2) Copy this file to somewhere (e.g. ~/.git-subtree-completion.sh);
+#    3) Added the following line to your .bashrc:
+#        source ~/.git-subtree-completion.sh
+#
+
+_git_subtree ()
+{
+        local cur="${COMP_WORDS[COMP_CWORD]}"
+
+        if [ $COMP_CWORD -eq 2 ]; then
+                __gitcomp "add merge pull push split"
+                return
+        elif [ $COMP_CWORD -eq 3 ]; then
+                __gitcomp "--prefix="
+                return
+        fi
+        __gitcomp "$(__git_remotes)"
+}

lib/facter/git_exec_path.rb

@@ -0,0 +1,4 @@
+# git_exec_path.rb
+Facter.add('git_exec_path') do
+  setcode 'git --exec-path 2>/dev/null'
+end

lib/facter/git_version.rb

@@ -0,0 +1,4 @@
+# git_version
+Facter.add('git_version') do
+  setcode 'git --version 2>/dev/null'
+end

manifests/subtree.pp

@@ -0,0 +1,41 @@
+# == Class: git::subtree
+#
+# Installs and configure git-subtree
+#
+class git::subtree {
+
+  Package['git'] -> Class['git::subtree']
+
+  if (versioncmp('1.7.0', $::git_version) >= 0) {
+    fail 'git-subtree requires git 1.7 or later!'
+  }
+
+  if (versioncmp('1.7.11', $::git_version) >= 0) {
+    $source_dir = '/usr/src/git-subtree'
+    vcsrepo { $source_dir:
+      ensure   => present,
+      source   => 'http://github.com/apenwarr/git-subtree.git',
+      provider => 'git',
+      revision => '2793ee6ba',
+    }
+  } else {
+    $source_dir = '/usr/share/doc/git-core/contrib/subtree'
+  }
+
+  exec { "/usr/bin/make prefix=/usr libexecdir=${::git_exec_path}":
+    creates => "${source_dir}/git-subtree",
+    cwd     => $source_dir,
+  }
+  ->
+  exec { "/usr/bin/make prefix=/usr libexecdir=${::git_exec_path} install":
+    creates => "${::git_exec_path}/git-subtree",
+    cwd     => $source_dir,
+  }
+
+  file { '/etc/bash_completion.d/git-subtree':
+    ensure => file,
+    source => 'puppet:///modules/git/subtree/bash_completion.sh',
+    mode   => '0644',
+  }
+
+}