Bug#36313839 Add "bundled" tcmalloc [patches]

Add support for cmake option -DWITH_TCMALLOC=bundled
This is supported on Linux only.

Add an IMPORTED library my_tcmalloc, which is linked into all
executables (the external name is libtcmalloc.so.9.16.5).
We build it using cmake's EXTERNALPROJECT_ADD functionality.

Change-Id: I6553fdde55d651294db3112067e84ef9d423b793
(cherry picked from commit 0ce1e9e579107480ad3fb2a9371279ef76a5cc4a)

Author: Tor Didriksen

CMakeLists.txt

@@ -2023,6 +2023,12 @@ IF(LINUX)
   HAVE_PTHREAD_SETNAME_NP)
 ENDIF()
 
+# The bundled version must be set up after all the configure stuff above.
+IF(LINUX AND WITH_TCMALLOC STREQUAL "bundled")
+  ADD_SUBDIRECTORY(${CMAKE_SOURCE_DIR}/extra/gperftools)
+  SET(MALLOC_LIBRARY "${CMAKE_BINARY_DIR}/lib/libtcmalloc.so")
+ENDIF()
+
 # Cannot use system tirpc with custom OpenSSL
 IF(WITH_SSL_PATH AND (LINUX_RHEL8 OR LINUX_RHEL9))
   SET(WITH_TIRPC "bundled")

cmake/malloc_utils.cmake

@@ -40,6 +40,10 @@ FUNCTION(WARN_MISSING_SYSTEM_JEMALLOC)
 ENDFUNCTION()
 
 FUNCTION(FIND_MALLOC_LIBRARY library_name)
+  # Skip system tcmalloc, and build the bundled version instead.
+  IF(WITH_TCMALLOC STREQUAL "bundled")
+    RETURN()
+  ENDIF()
   FIND_LIBRARY(MALLOC_LIBRARY ${library_name})
   IF(NOT MALLOC_LIBRARY)
     IF(library_name MATCHES "tcmalloc")

cmake/mysql_add_executable.cmake

@@ -83,6 +83,7 @@ FUNCTION(MYSQL_ADD_EXECUTABLE target_arg)
     EXCLUDE_FROM_ALL   # add target, but do not build it by default
     EXCLUDE_FROM_PGO   # add target, but do not build for PGO
     SKIP_INSTALL       # do not install it
+    SKIP_TCMALLOC      # do not link with tcmalloc
     )
   SET(EXECUTABLE_ONE_VALUE_KW
     ADD_TEST           # add unit test, sets SKIP_INSTALL
@@ -121,6 +122,19 @@ FUNCTION(MYSQL_ADD_EXECUTABLE target_arg)
   ADD_EXECUTABLE(${target} ${sources})
   TARGET_COMPILE_FEATURES(${target} PUBLIC cxx_std_17)
 
+  IF(TARGET my_tcmalloc)
+    IF(ARG_SKIP_TCMALLOC OR target MATCHES "^rpd")
+      # nothing, use glibc malloc/free
+    ELSE()
+      IF(WITH_VALGRIND)
+        TARGET_LINK_LIBRARIES(${target} my_tcmalloc_debug)
+      ELSE()
+        TARGET_LINK_LIBRARIES(${target} my_tcmalloc)
+      ENDIF()
+      ADD_INSTALL_RPATH(${target} "\$ORIGIN/../${INSTALL_PRIV_LIBDIR}")
+    ENDIF()
+  ENDIF()
+
   SET_PATH_TO_CUSTOM_SSL_FOR_APPLE(${target})
 
   IF(ARG_DEPENDENCIES)

extra/gperftools/CMakeLists.txt

@@ -0,0 +1,92 @@
+# Copyright (c) 2024, Oracle and/or its affiliates.
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License, version 2.0,
+# as published by the Free Software Foundation.
+#
+# This program is designed to work with certain software (including
+# but not limited to OpenSSL) that is licensed under separate terms,
+# as designated in a particular file or component or in included license
+# documentation.  The authors of MySQL hereby grant you an additional
+# permission to link the program and your derivative works with the
+# separately licensed software that they have either included with
+# the program or referenced in the documentation.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License, version 2.0, for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software
+# Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301  USA
+
+INCLUDE(ExternalProject)
+
+SET(TCMALLOC_SOURCE_DIR
+  "${CMAKE_SOURCE_DIR}/extra/gperftools/gperftools-2.15"
+  )
+
+FIND_PROGRAM(MAKE_EXECUTABLE make)
+
+SET(TCMALLOC_CMAKE_ARGS
+  -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER}
+  -DCMAKE_CXX_COMPILER=${CMAKE_CXX_COMPILER}
+  -DGPERFTOOLS_BUILD_STATIC=OFF
+  -Dgperftools_build_benchmark=OFF
+  -Dgperftools_enable_libunwind=OFF
+  -DBUILD_TESTING=OFF
+  -DCMAKE_INSTALL_PREFIX=${CMAKE_BINARY_DIR}/tcmalloc
+  -DCMAKE_INSTALL_LIBDIR=${CMAKE_BINARY_DIR}/library_output_directory
+)
+
+IF(LINUX_RHEL AND ALTERNATIVE_GCC)
+  LIST(APPEND TCMALLOC_CMAKE_ARGS -DCMAKE_C_FLAGS="-B${GCC_B_PREFIX}")
+  LIST(APPEND TCMALLOC_CMAKE_ARGS -DCMAKE_CXX_FLAGS="-B${GCC_B_PREFIX}")
+ENDIF()
+
+IF(ALTERNATIVE_LD)
+  LIST(APPEND TCMALLOC_CMAKE_ARGS -DCMAKE_LINKER=${ALTERNATIVE_LD})
+ENDIF()
+
+IF(ALTERNATIVE_AR)
+  LIST(APPEND TCMALLOC_CMAKE_ARGS -DCMAKE_AR=${ALTERNATIVE_AR})
+ENDIF()
+
+IF(ALTERNATIVE_RANLIB)
+  LIST(APPEND TCMALLOC_CMAKE_ARGS -DCMAKE_RANLIB=${ALTERNATIVE_RANLIB})
+ENDIF()
+
+EXTERNALPROJECT_ADD(tcmalloc_ext
+  SOURCE_DIR ${TCMALLOC_SOURCE_DIR}
+  CMAKE_ARGS ${TCMALLOC_CMAKE_ARGS}
+  BUILD_BYPRODUCTS
+  "${CMAKE_BINARY_DIR}/lib/libtcmalloc.so"
+  "${CMAKE_BINARY_DIR}/lib/libtcmalloc.so.9.16.5"
+  "${CMAKE_BINARY_DIR}/lib/libtcmalloc_debug.so"
+  "${CMAKE_BINARY_DIR}/lib/libtcmalloc_debug.so.9.16.5"
+  )
+
+# Cannot use INSTALL_PRIVATE_LIBRARY because these are not targets.
+INSTALL(FILES
+  "${CMAKE_BINARY_DIR}/lib/libtcmalloc.so"
+  "${CMAKE_BINARY_DIR}/lib/libtcmalloc.so.9.16.5"
+  DESTINATION "${INSTALL_PRIV_LIBDIR}" COMPONENT SharedLibraries
+  PERMISSIONS
+  OWNER_READ OWNER_WRITE OWNER_EXECUTE
+  GROUP_READ GROUP_EXECUTE
+  WORLD_READ WORLD_EXECUTE
+)
+
+ADD_LIBRARY(my_tcmalloc SHARED IMPORTED GLOBAL)
+SET_TARGET_PROPERTIES(my_tcmalloc PROPERTIES
+  IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+  IMPORTED_LOCATION "${CMAKE_BINARY_DIR}/lib/libtcmalloc.so")
+
+ADD_LIBRARY(my_tcmalloc_debug SHARED IMPORTED GLOBAL)
+SET_TARGET_PROPERTIES(my_tcmalloc_debug PROPERTIES
+  IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+  IMPORTED_LOCATION "${CMAKE_BINARY_DIR}/lib/libtcmalloc_debug.so")
+
+ADD_DEPENDENCIES(my_tcmalloc tcmalloc_ext)
+ADD_DEPENDENCIES(my_tcmalloc_debug tcmalloc_ext)

extra/gperftools/gperftools-2.15/CMakeLists.txt

@@ -1483,7 +1483,7 @@ install(FILES
         ${CMAKE_CURRENT_BINARY_DIR}/libprofiler.pc
         DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
 
-message(WARNING "note: gperftools' cmake support is incomplete and is best-effort only")
+# message(WARNING "note: gperftools' cmake support is incomplete and is best-effort only")
 
 #TODO @GENERATE_CHANGELOG_RULES@
 #TODO dist

sql/CMakeLists.txt

@@ -1187,7 +1187,10 @@ IF(NOT mysqld_link_flags)
   SET(mysqld_link_flags)
 ENDIF()
 
-IF(UNIX_INSTALL_RPATH_ORIGIN_PRIV_LIBDIR OR LINUX_INSTALL_RPATH_ORIGIN)
+IF(UNIX_INSTALL_RPATH_ORIGIN_PRIV_LIBDIR
+    OR LINUX_INSTALL_RPATH_ORIGIN
+    OR TARGET my_tcmalloc
+    )
   # Because of INSTALL_DEBUG_TARGET which does INSTALL(FILES ...)
   IF(UNIX AND NOT APPLE AND CMAKE_BUILD_TYPE_UPPER STREQUAL "DEBUG")
     STRING_APPEND(mysqld_link_flags