New projection system for keyword highlighting

Author: tpope

after/syntax/ruby/rails.vim

@@ -9,6 +9,7 @@ hi def link rubyMacro                       Macro
 hi def link rubyRoute                       rubyControl
 hi def link rubySchema                      rubyControl
 hi def link rubyResponse                    rubyControl
+hi def link rubyAction                      rubyControl
 hi def link rubyUrlHelper                   rubyHelper
 hi def link rubyViewHelper                  rubyHelper
 hi def link rubyTestHelper                  rubyHelper
@@ -228,14 +229,31 @@ syn keyword rubyAttribute cattr_accessor cattr_reader cattr_writer mattr_accesso
 syn keyword rubyAttribute thread_cattr_accessor thread_cattr_reader thread_cattr_writer thread_mattr_accessor thread_mattr_reader thread_mattr_writer
 syn keyword rubyMacro alias_attribute concern concerning delegate delegate_missing_to with_options
 
-let s:keywords = split(join(filter(rails#buffer().projected('keywords'),
-      \ 'type(v:val) == type("")'), ' '))
-let s:special = filter(copy(s:keywords), 'v:val =~# ''^\h\k*[?!]$''')
-let s:regular = filter(copy(s:keywords), 'v:val =~# ''^\h\k*$''')
-let s:group = rails#buffer().type_name('helper', 'view') ? 'rubyHelper' : 'rubyMacro'
-if !empty(s:special)
-  exe 'syn match' s:group '"\<\%('.join(s:special, '\|').'\)"'
-endif
-if !empty(s:regular)
-  exe 'syn keyword' s:group join(s:regular, ' ')
-endif
+let s:special = {
+      \ '[': '\>\[\@=',
+      \ ']': '\>[[.]\@!',
+      \ '{': '\>\%(\s*{\|\s*do\>\)\@=',
+      \ '}': '\>\%(\s*{\|\s*do\>\)\@!'}
+function! s:highlight(group, ...) abort
+  let value = rails#buffer().projected(a:0 ? a:1 : a:group)
+  let words = split(join(filter(value, 'type(v:val) == type("")'), ' '))
+  let special = filter(copy(words), 'type(v:val) == type("") && v:val =~# ''^\h\k*[][{}?!]$''')
+  let regular = filter(copy(words), 'type(v:val) == type("") && v:val =~# ''^\h\k*$''')
+  if !empty(special)
+    exe 'syn match' a:group substitute(
+          \ '"\<\%('.join(special, '\|').'\)"',
+          \ '[][{}]', '\=get(s:special, submatch(0), submatch(0))', 'g')
+  endif
+  if !empty(regular)
+    exe 'syn keyword' a:group join(regular, ' ')
+  endif
+endfunction
+
+call s:highlight(
+      \ rails#buffer().type_name('helper', 'view') ? 'rubyHelper' : 'rubyMacro',
+      \ 'keywords')
+call s:highlight('rubyMacro')
+call s:highlight('rubyAction')
+call s:highlight('rubyHelper')
+call s:highlight('rubyEntity')
+call s:highlight('rubyEntities')

doc/rails.txt

@@ -633,7 +633,7 @@ Vim syntax looks a lot like JSON, but with funky |line-continuation|:
 	      \     "test/unit/{}_uploader_test.rb",
 	      \     "spec/models/{}_uploader_spec.rb"
 	      \   ],
-	      \   "keywords": "process version"
+	      \   "rubyMacro": ["process", "version"]
 	      \ },
 	      \ "features/support/*.rb": {"command": "support"},
 	      \ "features/support/env.rb": {"command": "support"}}
@@ -682,7 +682,7 @@ The full list of available options is as follows:
 	Determines the |:compiler| plugin to use with |rails-:Runner|.
 						*rails-projection-keywords*
 "keywords" ~
-	Provides a whitespace delimited list of keywords to syntax highlight.
+	Obsolete: see rubyMacro, rubyAction, and rubyHelper below.
 						*rails-projection-command*
 "command" ~
 	Names a navigation command to be created.  Use the same name on
@@ -705,11 +705,23 @@ The full list of available options is as follows:
 	If you provide a ! after the argument to the navigation command (that
 	is, :Euploader foo!, NOT :Euploader! foo), and a new file is created,
 	this will be used as an array of lines to populate the body.
-						*rails-projection-params*
+						*rails-projection-railsParams*
 "railsParams" ~
 	Provides a dictionary of defaults for URL parameters for
 	|rails-:Preview|, for example {"user_id": "2"}.  The fallback for
 	unspecified parameters is "1".
+						*rails-projection-rubyMacro*
+"rubyMacro" ~
+	List of keywords to highlight as class declarations (like
+	before_action or validates_presence_of).
+						*rails-projection-rubyAction*
+"rubyAction" ~
+	List of keywords to highlight as imperative methods (like
+	redirect_to or create_table).
+						*rails-projection-rubyHelper*
+"rubyHelper" ~
+	List of keywords to highlight as functional methods (like
+	params or any view helper).
 
 CONFIGURATION					*rails-configuration*