Bug#19187034: ADD COMPILER VERSION CHECKS TO CMAKE

Add CMake checks for minimum version of supported compilers:
  gcc (Linux, Solaris): 4.4
  Sun Studio (Solaris client lib): 12u2
  clang (Mac OS X, FreeBSD): 3.3

A similar check for Visual Studio 2013 already exists.

The patch also adds a new CMake option -DFORCE_UNSPPORTED_COMPILER
which if set disables the compiler version check.

Author: jhauglid

CMakeLists.txt

@@ -232,7 +232,8 @@ ENDIF()
 IF(NOT WITHOUT_SERVER)
   OPTION (WITH_UNIT_TESTS "Compile MySQL with unit tests" ON)
 ENDIF()
-MARK_AS_ADVANCED(WITHOUT_SERVER DISABLE_SHARED)
+OPTION(FORCE_UNSUPPORTED_COMPILER "Disable compiler version checks" OFF)
+MARK_AS_ADVANCED(WITHOUT_SERVER DISABLE_SHARED FORCE_UNSUPPORTED_COMPILER)
 
 
 include(CheckCSourceCompiles)

cmake/os/Darwin.cmake

@@ -1,4 +1,4 @@
-# Copyright (c) 2010, 2012, Oracle and/or its affiliates. All rights reserved.
+# Copyright (c) 2010, 2014, Oracle and/or its affiliates. All rights reserved.
 # 
 # This program is free software; you can redistribute it and/or modify
 # it under the terms of the GNU General Public License as published by
@@ -15,6 +15,25 @@
 
 # This file includes OSX specific options and quirks, related to system checks
 
+INCLUDE(CheckCSourceRuns)
+
+# We require at least Clang 3.3 (XCode 5).
+IF(NOT FORCE_UNSUPPORTED_COMPILER)
+  IF(CMAKE_C_COMPILER_ID MATCHES "Clang")
+    CHECK_C_SOURCE_RUNS("
+      int main()
+      {
+        return (__clang_major__ < 3) ||
+               (__clang_major__ == 3 && __clang_minor__ < 3);
+      }" HAVE_SUPPORTED_CLANG_VERSION)
+    IF(NOT HAVE_SUPPORTED_CLANG_VERSION)
+      MESSAGE(FATAL_ERROR "Clang 3.3 or newer is required!")
+    ENDIF()
+  ELSE()
+    MESSAGE(FATAL_ERROR "Unsupported compiler!")
+  ENDIF()
+ENDIF()
+
 # This is used for the version_compile_machine variable.
 IF(CMAKE_SIZEOF_VOID_P MATCHES 8)
   SET(MYSQL_MACHINE_TYPE "x86_64")

cmake/os/FreeBSD.cmake

@@ -16,6 +16,25 @@
 
 # This file includes FreeBSD specific options and quirks, related to system checks
 
+INCLUDE(CheckCSourceRuns)
+
+# We require at least Clang 3.3.
+IF(NOT FORCE_UNSUPPORTED_COMPILER)
+  IF(CMAKE_C_COMPILER_ID MATCHES "Clang")
+    CHECK_C_SOURCE_RUNS("
+      int main()
+      {
+        return (__clang_major__ < 3) ||
+               (__clang_major__ == 3 && __clang_minor__ < 3);
+      }" HAVE_SUPPORTED_CLANG_VERSION)
+    IF(NOT HAVE_SUPPORTED_CLANG_VERSION)
+      MESSAGE(FATAL_ERROR "Clang 3.3 or newer is required!")
+    ENDIF()
+  ELSE()
+    MESSAGE(FATAL_ERROR "Unsupported compiler!")
+  ENDIF()
+ENDIF()
+
 # Should not be needed any more, but kept for easy resurrection if needed
 #   #Legacy option, maybe not needed anymore , taken as is from autotools build
 #   ADD_DEFINITIONS(-DNET_RETRY_COUNT=1000000)

cmake/os/Linux.cmake

@@ -17,6 +17,30 @@
 # This file includes Linux specific options and quirks, related to system checks
 
 INCLUDE(CheckSymbolExists)
+INCLUDE(CheckCSourceRuns)
+
+# We require at least GCC 4.4 or Clang 3.3.
+IF(NOT FORCE_UNSUPPORTED_COMPILER)
+  IF(CMAKE_COMPILER_IS_GNUCC)
+    EXECUTE_PROCESS(COMMAND ${CMAKE_C_COMPILER} -dumpversion
+                    OUTPUT_VARIABLE GCC_VERSION)
+    IF(GCC_VERSION VERSION_LESS 4.4)
+      MESSAGE(FATAL_ERROR "GCC 4.4 or newer is required!")
+    ENDIF()
+  ELSEIF(CMAKE_C_COMPILER_ID MATCHES "Clang")
+    CHECK_C_SOURCE_RUNS("
+      int main()
+      {
+        return (__clang_major__ < 3) ||
+               (__clang_major__ == 3 && __clang_minor__ < 3);
+      }" HAVE_SUPPORTED_CLANG_VERSION)
+    IF(NOT HAVE_SUPPORTED_CLANG_VERSION)
+      MESSAGE(FATAL_ERROR "Clang 3.3 or newer is required!")
+    ENDIF()
+  ELSE()
+    MESSAGE(FATAL_ERROR "Unsupported compiler!")
+  ENDIF()
+ENDIF()
 
 # ISO C89, ISO C99, POSIX.1, POSIX.2, BSD, SVID, X/Open, LFS, and GNU extensions.
 ADD_DEFINITIONS(-D_GNU_SOURCE)

cmake/os/SunOS.cmake

@@ -18,6 +18,31 @@ INCLUDE(CheckCSourceRuns)
 INCLUDE(CheckCSourceCompiles) 
 INCLUDE(CheckCXXSourceCompiles)
 
+# We require at least GCC 4.4 or SunStudio 12u2 (CC 5.11)
+IF(NOT FORCE_UNSUPPORTED_COMPILER)
+  IF(CMAKE_COMPILER_IS_GNUCC)
+    EXECUTE_PROCESS(COMMAND ${CMAKE_C_COMPILER} -dumpversion
+                    OUTPUT_VARIABLE GCC_VERSION)
+    IF(GCC_VERSION VERSION_LESS 4.4)
+      MESSAGE(FATAL_ERROR "GCC 4.4 or newer is required!")
+    ENDIF()
+  ELSEIF(CMAKE_C_COMPILER_ID MATCHES "SunPro")
+    EXECUTE_PROCESS(
+      COMMAND ${CMAKE_CXX_COMPILER} "-V"
+      OUTPUT_VARIABLE stdout
+      ERROR_VARIABLE  stderr
+      RESULT_VARIABLE result
+    )
+    STRING(REGEX MATCH "CC: Sun C\\+\\+ 5\\.([0-9]+)" VERSION_STRING ${stderr})
+    SET(MINOR_VERSION ${CMAKE_MATCH_1})
+    IF(${MINOR_VERSION} LESS 11)
+      MESSAGE(FATAL_ERROR "SunStudio 12u2 or newer is required!")
+    ENDIF()
+  ELSE()
+    MESSAGE(FATAL_ERROR "Unsupported compiler!")
+  ENDIF()
+ENDIF()
+
 # Enable 64 bit file offsets
 ADD_DEFINITIONS(-D_FILE_OFFSET_BITS=64)
 

cmake/os/Windows.cmake

@@ -36,7 +36,7 @@ GET_FILENAME_COMPONENT(_SCRIPT_DIR ${CMAKE_CURRENT_LIST_FILE} PATH)
 INCLUDE(${_SCRIPT_DIR}/WindowsCache.cmake)
 
 # We require at least Visual Studio 2013 (aka 12.0) which has version nr 1800.
-IF(MSVC_VERSION LESS 1800)
+IF(NOT FORCE_UNSUPPORTED_COMPILER AND MSVC_VERSION LESS 1800)
   MESSAGE(FATAL_ERROR "Visual Studio 2013 or newer is required!")
 ENDIF()