tutorials/io/background_loading

[giscus[bot]]

tutorials/io/background_loading

Commonly, games need to load resources asynchronously. When switching the main scene of your game (e.g. going to a new level), you might want to show a loading screen with some indication that prog...

https://docs.godotengine.org/en/stable/tutorials/io/background_loading.html

[terraquad]

The example doesn't demonstrate the use of ResourceLoader.load_threaded_get_status(). It should probably be checked in the _on_button_pressed() function before calling ResourceLoader.load_threaded_get()

[TranquilMarmot]

A more complete example getting the progress percentage with a progress bar:

extends Control
class_name LoadingScreen

## This is emitted when the scene is finished loading.
## Use `ResourceLoader.load_threaded_get(path)` to get the scene.
signal scene_loaded(path: String)

@onready var progress_bar = %ProgressBar

## The path to the scene that's actually being loaded
var path: String

## Actual progress value; we move towards towards this
var progress_value := 0.0


## Load the scene at the given path.
## When this is finished loading, the "scene_loaded" signal will be emitted.
func load(path_to_load: String):
	path = path_to_load
	ResourceLoader.load_threaded_request(path)


func _process(delta: float):
	if not path:
		return

	var progress = []
	var status = ResourceLoader.load_threaded_get_status(path, progress)

	if status == ResourceLoader.ThreadLoadStatus.THREAD_LOAD_IN_PROGRESS:
		progress_value = progress[0] * 100
		progress_bar.value = move_toward(progress_bar.value, progress_value, delta * 20)

	if status == ResourceLoader.ThreadLoadStatus.THREAD_LOAD_LOADED:
		# zip the progress bar to 100% so we don't get weird visuals
		progress_bar.value = move_toward(progress_bar.value, 100.0, delta * 150)

		# "done" loading :)
		if progress_bar.value >= 99:
			scene_loaded.emit(path)

[mintymelinda]

I had to use $ProgressBar instead of %ProgressBar but this works beautifully thanks.

[sweetbbak]

you have to mark the node as "Access as Unique Name" to use %NodeName which will allow you to reference a node without knowing its exact path. Its pretty handy so that you don't have to waste time fixing hard coded paths if you move something around. You could always reference child nodes to a unique node pretty easily