Add a second template for a header-only library

Author: claudiofantacci

CMakeLists.txt

@@ -18,10 +18,10 @@ cmake_minimum_required(VERSION 3.5)
 # listed here: https://cmake.org/cmake/help/latest/command/project.html.
 # We use this name to export all the files such that is then possible to use
 # find_package(LibTemplateCMake) in third party projects.
-# LANGUAGES specifies which languages your project supports. To have a broad 
-# support with external libraries, it is good practice to list both CXX and C. 
-# Infact, some legacy Find<package>.cmake files that require the C language to 
-# be enabled and thus using only CXX may cause issues. Note that by default when 
+# LANGUAGES specifies which languages your project supports. To have a broad
+# support with external libraries, it is good practice to list both CXX and C.
+# Infact, some legacy Find<package>.cmake files that require the C language to
+# be enabled and thus using only CXX may cause issues. Note that by default when
 # LANGUAGES is not specified CMake enables both CXX and C.
 project(LibTemplateCMake
         LANGUAGES CXX C
@@ -141,7 +141,6 @@ include(InstallBasicPackageFiles)
 install_basic_package_files(${PROJECT_NAME}
                             VERSION ${${PROJECT_NAME}_VERSION}
                             COMPATIBILITY AnyNewerVersion
-                            EXPORT ${PROJECT_NAME}
                             VARS_PREFIX ${PROJECT_NAME}
                             NO_CHECK_REQUIRED_COMPONENTS_MACRO)
 # Add the uninstall target

src/CMakeLists.txt

@@ -1,2 +1,3 @@
 add_subdirectory(LibTemplateCMake)
+add_subdirectory(LibHeaderOnlyTemplateCMake)
 add_subdirectory(ExeExample)

src/LibHeaderOnlyTemplateCMake/CMakeLists.txt

@@ -0,0 +1,66 @@
+# This is the "physical" (i.e. real) name of the library.
+# The actual file name of the library built is constructed based on conventions
+# of the native platform, such as lib<LIBRARY_TARGET_NAME>.a,
+# lib<LIBRARY_TARGET_NAME>.dylib or <LIBRARY_TARGET_NAME>.lib.
+set(LIBRARY_TARGET_NAME ${PROJECT_NAME}HeaderOnly)
+
+# List of HPP (header) library files.
+set(${LIBRARY_TARGET_NAME}_HDR
+        include/LibHeaderOnlyTemplateCMake/LibHeaderOnlyTemplateCMake.h
+)
+
+# You can add an external dependency using the find_package() function call
+# See: https://cmake.org/cmake/help/latest/command/find_package.html
+# Note that the imported objects resulting from the find_package() depends upon
+# the configuration files generated by the developer of the library.
+# These imported objects can be either:
+#  - variables that must be used to include directories and/or link libraries
+#    with function calls like target_include_directories() and/or
+#    target_link_libraries();
+#  - a CMake target that must only be linked using target_link_libraries() and
+#    CMake will take care of including and/or linking the appropriate
+#    directories and/or libraries.
+# See: https://cmake.org/cmake/help/latest/command/target_include_directories.html
+# See: https://cmake.org/cmake/help/latest/command/target_link_libraries.html
+# For example:
+# find_package(FooPackage) may import either
+#  - variables: FooPackage_INCLUDE_DIRS and FooPackage_LIBRARIES
+#  - target: FooPackage::FooPackage
+
+# Adds a library target called ${LIBRARY_TARGET_NAME} to be built from the
+# source and header files listed in the command invocation.
+add_library(${LIBRARY_TARGET_NAME} INTERFACE)
+
+# Within this project, you can link to this library by just specifing the name
+# of the target, i.e. ${LIBRARY_TARGET_NAME} = LibTemplateCMakeHeaderOnly. It is
+# useful, however, to define an alias of this library with the scope of the
+# exported library itself because (1) you will link against it with the exact
+# same syntax of an imported library and (2) because names having a double-colon
+# (::) are always treated as the name of either an alias or imported target. Any
+# attempt to use such a name for a different target type will result in an error.
+add_library(${PROJECT_NAME}::${LIBRARY_TARGET_NAME} ALIAS ${LIBRARY_TARGET_NAME})
+
+# Specify include directories for both compilation and installation process.
+# The $<INSTALL_PREFIX> generator expression is useful to ensure to create
+# relocatable configuration files, see https://cmake.org/cmake/help/latest/manual/cmake-packages.7.html#creating-relocatable-packages
+target_include_directories(${LIBRARY_TARGET_NAME} INTERFACE "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>"
+                                                            "$<INSTALL_INTERFACE:$<INSTALL_PREFIX>/${CMAKE_INSTALL_INCLUDEDIR}>")
+
+# If you used find_package() you need to use target_include_directories() and/or
+# target_link_libraries(). As explained previously, depending on the imported
+# objects, you may need to call either or both:
+# - with imported variable:
+#   target_include_directories(${LIBRARY_TARGET_NAME} ${FooPackage_INCLUDE_DIRS})
+#   target_link_libraries(${LIBRARY_TARGET_NAME} ${FooPackage_LIBRARIES})
+# - with imported target:
+#   target_link_libraries(${LIBRARY_TARGET_NAME} FooPackage_LIBRARIES::FooPackage_LIBRARIES)
+
+# Specify installation targets, typology and destination folders.
+install(TARGETS ${LIBRARY_TARGET_NAME}
+        EXPORT  ${PROJECT_NAME})
+
+install(FILES ${${LIBRARY_TARGET_NAME}_HDR}
+        DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/${LIBRARY_TARGET_NAME}")
+
+
+message(STATUS "Created target ${LIBRARY_TARGET_NAME} for export ${PROJECT_NAME}.")

src/LibHeaderOnlyTemplateCMake/include/LibHeaderOnlyTemplateCMake/LibHeaderOnlyTemplateCMake.h

@@ -0,0 +1,33 @@
+#ifndef LIB_TEMPLATE_CMAKE_H
+#define LIB_TEMPLATE_CMAKE_H
+
+namespace LibTemplateCMake {
+
+/**
+ * \brief Computes the sum of two values.
+ * \param op1 first input value.
+ * \param op2 second input value.
+ * \returns sum of op1 and op2.
+ */
+template<typename DatumType>
+DatumType sum(DatumType op1, DatumType op2)
+{
+    return (op1 + op2);
+}
+
+
+/**
+ * \brief Computes the difference of two values.
+ * \param op1 first input value.
+ * \param op2 second input value.
+ * \returns difference of op1 and op2.
+ */
+template<typename DatumType>
+DatumType sub(DatumType op1, DatumType op2)
+{
+    return (op1 - op2);
+}
+
+} // namespace LibTemplateCMake
+
+#endif /* LIB_TEMPLATE_CMAKE_H */

src/LibTemplateCMake/CMakeLists.txt

@@ -3,10 +3,21 @@
 # of the native platform, such as lib<LIBRARY_TARGET_NAME>.a,
 # lib<LIBRARY_TARGET_NAME>.dylib or <LIBRARY_TARGET_NAME>.lib.
 #
-# In order to use a library name that is not the same as the `EXPORT` (in the
-# `install` command), it is necessary to pass the `FIRST_TARGET` option to
-# `install_basic_package_files` in the main CMakeLists.txt file.
-# In this case the project name is used for both, therefore it is not necessary.
+# In order to use a library name LIBRARY_TARGET_NAME that is not the same as the
+# `EXPORT` used in the `install` command (see the end of this file), it is
+# required to use `FIRST_TARGET` option of the `install_basic_package_files`
+# command in the main CMakeLists.txt file with the name of one of the exported
+# targets. `FIRST_TARGET` option defaults to LIBRARY_TARGET_NAME.
+# By using setting LIBRARY_TARGET_NAME to ${PROJECT_NAME} it is not necessary to
+# use `FIRST_TARGET` option in the main CMakeLists.txt.
+# In general, withing a C++ project, there is at least one exported target whose
+# name is always know. Consequently, `FIRST_TARGET` option in the main
+# CMakeLists.txt can be statically set to such target name. In the context of
+# projects where users may choose what target to export, thus the name of a
+# target may change at configure time, you can use propagate back to parent
+# CMakeLists.txt, up to the main one, a variable containing the name of a
+# target. In order to do it, you can use `set` command with `PARENT_SCOPE`
+# option, see https://cmake.org/cmake/help/latest/command/set.html.
 set(LIBRARY_TARGET_NAME ${PROJECT_NAME})
 
 # List of CPP (source) library files.
@@ -78,3 +89,6 @@ install(TARGETS ${LIBRARY_TARGET_NAME}
         ARCHIVE       DESTINATION "${CMAKE_INSTALL_LIBDIR}"                            COMPONENT lib
         RUNTIME       DESTINATION "${CMAKE_INSTALL_BINDIR}"                            COMPONENT bin
         PUBLIC_HEADER DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/${LIBRARY_TARGET_NAME}" COMPONENT dev)
+
+
+message(STATUS "Created target ${LIBRARY_TARGET_NAME} for export ${PROJECT_NAME}.")